Asp深度揭密（上）

發(fā)布時間：2008-07-09 閱讀數(shù)：次來源：網(wǎng)樂原科技

一、Asp基本知識

1．Asp是Active Server Pages的簡稱，是解釋型的腳本語言環(huán)境；
2．Asp的運(yùn)行需要Windows操作系統(tǒng)，9x下需要安裝PWS；而NT/2000/XP則需要安裝Internet Information Server（簡稱IIS）；
3．Asp和JSP的腳本標(biāo)簽是“<%%>”，PHP的則可以設(shè)定為多種；
4．Asp的注釋符號是“'”；
5.使用附加組件，可以擴(kuò)展Asp的功能。

例子：

HelloWorld_1.asp
<%="Hello,world"%>

效果：
Hello,world

HelloWorld_2.asp
<%
for i=1 to 10
response.write "Hello,world"
next
%>

效果：
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world

注意：Asp不區(qū)分大小寫；變量無需定義也可使用，轉(zhuǎn)換方便；語法檢查很松。

二、Asp內(nèi)置對象的使用：

可以使用下面的任何ASP內(nèi)置對象，而不必在ASP腳本中特別聲明。

1． Request：

定義：可用來訪問從瀏覽器發(fā)送到服務(wù)器的請求信息，可用此對象讀取已輸入HTML表單的信息。

集：
Cookies：含有瀏覽器cookies的值
Form：含有HTML表單域中的值
QueryString：含有查詢字符串的值
ServerVariables：含有頭和環(huán)境變量中的值

例子：

request_url.asp
<%
'獲取用戶輸入，并存入變量
user_id=request.querystring("user_id")
user_name=request.querystring("user_name")

'判斷用戶輸入是否正確
if user_id="" then
response.write "User_id is null,please check it"
response.end
end if
if user_name="" then
response.write "User_name is null,please check it"
response.end
end if

'打印變量
response.write user_id&"<br>"
response.write user_name
%>

效果：
當(dāng)訪問http://10.1.43.238/course/request_url.asp?user_name=j時：
User_id is null,please check it
當(dāng)訪問http://10.1.43.238/course/request_url.asp?user_name=j&user_id=my_id時：
my_id
j

思考：變量是如何在URL中傳遞和被Asp頁面獲取的？

request_form.htm
<style type="text/css">

</style>

request_form.asp
<%
'獲取用戶輸入，并存入變量
user_id=request.form("user_id")
user_name=request.form("user_name")

'打印變量
response.write user_id&"<br>"
response.write user_name
%>

注意：form的action的指向，request_form.asp和request_url.asp在源代碼上的區(qū)別？

2． Response：

定義：用來向瀏覽器回發(fā)信息，可用此對象從腳本向瀏覽器發(fā)送輸出。

集：
Cookies：在瀏覽器中加入一個cookie

方法：
End：結(jié)束腳本的處理
Redirect：將瀏覽器引導(dǎo)至新頁面
Write：向瀏覽器發(fā)送一個字符串

屬性：
Buffer：緩存一個ASP
CacheControl：由代理服務(wù)器控制緩存
ContentType：規(guī)定響應(yīng)的內(nèi)容類型
Expires：瀏覽器用相對時間控制緩存
ExpiresAbsolute：瀏覽器用絕對時間控制緩存

例子：

response_redirect.asp
<%
'去google看看吧
response.redirect "http://www2.google.com"
response.end
%>

response_cookies.asp
<%
'設(shè)置和讀取cookies
response.cookies("time_now")=now()
response.write request.cookies("time_now")
%>

效果：
當(dāng)訪問http://10.1.43.238/course/response_cookies.asp時：
2002-9-1 16:20:40

response_buffer.asp
<%'response.buffer=true%>
<a href="a">a</a>
<%response.redirect "request_form.htm"%>

效果：
①．當(dāng)關(guān)閉IIS的緩沖功能，訪問該頁面時出錯
a
答復(fù)對象錯誤 'ASP 0156 : 80004005'
頭錯
/course/response_buffer.asp，行3
HTTP 頭已經(jīng)寫入到客戶瀏覽器。任何 HTTP 頭的修改必須在寫入頁內(nèi)容之前。
②．當(dāng)關(guān)閉IIS的緩沖功能，去掉文件第一行的注釋，則頁面重定向成功
③．當(dāng)打開IIS的緩沖功能，無論是否去掉文件第一行的注釋，頁面重定向都成功

3． Server

定義：可在服務(wù)器上使用不同實體函數(shù)，如在時間到達(dá)前控制腳本執(zhí)行的時間。還可用來創(chuàng)建其他對象。

方法：
CreateObject：創(chuàng)建一個對象實例
HTMLEncode：將字符串轉(zhuǎn)化為使用特別的HTML字符
MapPath：把虛擬路徑轉(zhuǎn)化成物理路徑
URLEncode：把字符串轉(zhuǎn)化成URL編碼的
ScriptTimeout：在終止前，一個腳本允許運(yùn)行的秒數(shù)

例子：

server_htmlencode.asp
<%
'html encode
response.write server.htmlencode("a""time_now")
%>

效果：
a"time_now
查看源文件時顯示為：a"time_now

思考：為什么不是a""time_now這種效果？源文件是怎么了？

server_mappath.asp
<%
'mappath
response.write server.mappath("server_mappath.asp")
%>

效果：
G:\asp_www\test\course\server_mappath.asp

思考：如何獲取站點(diǎn)根目錄的實際路徑？如何獲取某個目錄的實際路徑？

server_urlencode.asp
<%
'url encode
response.write server.urlencode("a\time_now")
%>

效果：
a%5Ctime%5Fnow

4． Application

定義：用來存儲、讀取用戶共享的應(yīng)用程序信息，如可以用此對象在網(wǎng)站的用戶間傳送信息，當(dāng)服務(wù)器重啟后信息丟失。

方法：
Lock：防止其它用戶訪問Application集
Unlock：使其它用戶可以訪問Application集

事件：
OnEnd：由終止網(wǎng)絡(luò)服務(wù)器、改變Global.asa文件觸發(fā)
OnStart：由應(yīng)用程序中對網(wǎng)頁的第一次申請觸發(fā)

例子：

application_counter.asp
<%
'一個使用Application制作的簡單計數(shù)器
Application.lock
Application("clicks")=Application("clicks")+1
Application.unlock

response.write "您是本站第 "&Application("clicks")&" 位訪客！"
response.write "<br><br>您來自 "&request.servervariables("remote_addr")
%>

效果：
您是本站第 1 位訪客！

您來自 10.1.43.238

思考：本例中l(wèi)ock和unlock有何作用？

5． Session

定義：存儲、讀取特定用戶對話信息，如可存儲用戶對網(wǎng)站的訪問信息，當(dāng)服務(wù)器重啟后信息丟失。

方法：
Abandon：處理完當(dāng)前頁面后，結(jié)束一個用戶會話

屬性：
Timeout：用戶會話持續(xù)時間（分鐘數(shù)）

事件：
OnEnd：在Session Timeout時間以外，用戶不再申請頁面觸發(fā)該事件
OnStart：由用戶對網(wǎng)頁的第一次申請時觸發(fā)

例子：

session_counter.asp
<%
'一個使用Session制作的簡單計數(shù)器
session("clicks")=session("clicks")+1

response.write "您是本站第 "&session("clicks")&" 位訪客！"
response.write "<br><br>您來自 "&request.servervariables("remote_addr")
%>

效果：
您是本站第 1 位訪客！

您來自 10.1.43.238

思考：既然session和application都能做到計數(shù)，那它們之間有什么區(qū)別？如果要做到滿100重新開始計數(shù)如何實現(xiàn)？

三、使用Asp操作數(shù)據(jù)庫：

1．通過ODBC或者OLE方式連接的區(qū)別？

現(xiàn)在有兩種連接數(shù)據(jù)庫的方法。一方面，可以用ODBC產(chǎn)生一個連接，這種連接與任何有ODBC驅(qū)動器的數(shù)據(jù)庫（即基本上是市場上所有的數(shù)據(jù)庫）兼容；另一方面，可以用原始OLE DB提供商產(chǎn)生一個連接。

該用哪個提供商？盡可能用原始OLE DB提供商，因為它提供了對數(shù)據(jù)更有效的訪問。Microsoft正逐步用OLE DB取代ODBC標(biāo)準(zhǔn)，應(yīng)該僅僅在沒有原始OLE DB提供商時使用ODBC。

⑴．用ODBC方式連接SQL Server：
①．配置ODBC
②．連接代碼：
conn_odbc.asp
<%
Set Conn = Server.CreateObject("ADODB.Connection")
'Conn.Open "DSN=course_dsn;UID=course_user;PWD=course_password;DATABASE=course"
Conn.Open "course_dsn","course_user","course_password"
%>
注意：在配置MyDSN時若指定默認(rèn)數(shù)據(jù)庫為course則上述代碼作用想同，否則第二行的連接方式更有靈活性，可以指定連接某個數(shù)據(jù)庫（當(dāng)然，前提是course_user對這個數(shù)據(jù)庫有操作權(quán)限）。

⑵．用OLE方式連接SQL Server：
conn_ole.asp
<%
Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open "PROVIDER=SQLOLEDB;DATA SOURCE=10.1.43.238,2433; UID=course_user;PWD=course_password;DATABASE=course"
%>

2．操作數(shù)據(jù)庫：Connection和Recordset

聯(lián)合使用connection和recordset操作數(shù)據(jù)庫，或者只使用connection操作數(shù)據(jù)庫。

例子：

⑴．聯(lián)合使用connection和recordset操作數(shù)據(jù)庫

use_db_1.asp
<%
Set conn=Server.CreateObject("ADODB.Connection") '創(chuàng)建連接數(shù)據(jù)庫的對象
conn.Open "course_dsn","course_user","course_password" '使用該對象連接數(shù)據(jù)庫
Set rs=Server.CreateObject("ADODB.RecordSet") '創(chuàng)建記錄集對象
rs.Open "select * from user_info",conn,1,1 '使用記錄集對象打開數(shù)據(jù)庫
if rs.recordcount>0 then '如果有記錄
response.write "User_id User_name<br>"
for i=1 to rs.recordcount '循環(huán)讀取所有紀(jì)錄
response.write rs("id")&" "&rs("user_name")&"<br>"
'向瀏覽器輸出紀(jì)錄的字段
rs.movenext '指針下移一行
if rs.eof then exit for '如果到達(dá)記錄集底部則退出循環(huán)
next
end if
%>

效果：
User_id User_name
1 ahyi
3 test

⑵．只使用connection操作數(shù)據(jù)庫：

use_db_2.asp
<%
Set conn=Server.CreateObject("ADODB.Connection") '創(chuàng)建連接數(shù)據(jù)庫的對象
conn.Open "course_dsn","course_user","course_password" '使用該對象連接數(shù)據(jù)庫
conn.execute "delete from user_info"
%>

效果：
user_info表中所有數(shù)據(jù)被刪除

思考：兩種方式有和區(qū)別？各應(yīng)用于什么場合？

3．如何使用事務(wù)處理、存儲過程和視圖？

⑴．使用存儲過程

①．定義好存儲過程

CREATE PROCEDURE [output_1]
@sid int output
AS
set @sid=2

CREATE PROCEDURE [return_1]
(@user_name varchar(40),@password varchar(20))
AS
if exists(select id from user_info where user_name=@user_name and password=@password)
return 1
else
return 0

CREATE PROCEDURE [user_info_1]
(@user_name varchar(40),@password varchar(20))
AS
select id from user_info where user_name=@user_name and password=@password

CREATE PROCEDURE [user_info_2]
(@user_name varchar(40),@password varchar(20))
AS
SET XACT_ABORT ON
BEGIN TRANSACTION
delete from user_info where user_name=@user_name and password=@password
COMMIT TRANSACTION
SET XACT_ABORT OFF

CREATE PROCEDURE [user_info_3] AS
select * from user_info

②．在Asp中調(diào)用

use_proc.asp

<%
Set conn=Server.CreateObject("ADODB.Connection")
conn.Open "course_dsn","course_user","course_password"

'使用recordset調(diào)用帶兩個輸入?yún)?shù)和返回紀(jì)錄集的存儲過程
'CREATE PROCEDURE [user_info_1]
'(@user_name varchar(40),@password varchar(20))
'AS
'select id from user_info where user_name=@user_name and password=@password
response.write "普通的調(diào)用方法：<br>"
set rs=server.createobject("adodb.recordset")
sql="user_info_1 '"&request.querystring("user_name")&"','"&request.querystring("password")&"'"
rs.open sql,conn,1,1
response.write rs("id")&"<br>"
rs.close

'使用recordset調(diào)用無輸入?yún)?shù)，返回紀(jì)錄集的存儲過程，可以使用recordcount等屬性
'CREATE PROCEDURE [user_info_3] AS
'select * from user_info
response.write "<br>返回紀(jì)錄集，可以使用recordcount等屬性："
sql="exec user_info_3"
rs.open sql,conn,1,1
for i=1 to rs.recordcount
response.write "<br>"&rs("user_name")
rs.movenext
next
rs.close
set rs=nothing

'使用command調(diào)用帶輸出參數(shù)的存儲過程
'CREATE PROCEDURE [output_1]
'@sid int output
'AS
'set @sid=2
response.write "<br><br>調(diào)用帶輸出參數(shù)的存儲過程：<br>"
set cmd=server.createobject("adodb.command")
cmd.activeconnection=conn
cmd.commandtext = "output_1"
cmd.parameters.append cmd.createparameter("@sid",adinteger,adparamoutput)
cmd("@sid")=10
cmd.execute()
bbb=cmd("@sid")
response.write bbb&"<br>"
set cmd=nothing

'使用command調(diào)用帶兩個輸入?yún)?shù)和返回值的存儲過程
'CREATE PROCEDURE [return_1]
'(@user_name varchar(40))
'AS
'if exists(select id from user_info where user_name=@user_name)
'return 1
'else
'return 0
response.write "<br>調(diào)用帶兩個輸入?yún)?shù)和返回值的存儲過程：<br>"
set cmd=server.createobject("adodb.command")
cmd.activeconnection=conn
cmd.commandtype = adcmdstoredproc
cmd.commandtext = "return_1"
cmd.parameters.append cmd.createparameter("@return_value",adinteger,adparamreturnvalue)
cmd.parameters.append cmd.createparameter("@user_name",advarchar,adparaminput,40)
cmd.parameters.append cmd.createparameter("@password",advarchar,adparaminput,20)
cmd("@user_name")="tuth"
cmd("@password")="yyuyu"
cmd.execute()
rrr=cmd("@return_value")
response.write rrr
set cmd=nothing

conn.close
set conn=nothing
%>

效果：
訪問http://10.1.43.238/course/use_proc.asp?user_name=ahyi&password=ttt時，出現(xiàn)如下

普通的調(diào)用方法：
12

返回紀(jì)錄集，可以使用recordcount等屬性：
ahyi
tet
tuth

調(diào)用帶輸出參數(shù)的存儲過程：
2

調(diào)用帶兩個輸入?yún)?shù)和返回值的存儲過程：
1

注意：若存儲過程無參數(shù)，則調(diào)用的sql語句直接為存儲過程名，一個參數(shù)為“存儲過程名參數(shù)”，若是多個參數(shù)，則“存儲過程名參數(shù)1，參數(shù)2，……，參數(shù)n”；如果在sql語句中加入exec，則在返回的記錄集中可以使用recordcount等屬性；如果想獲得存儲過程的返回值或輸出參數(shù)，可以使用command對象。

⑵．使用事務(wù)處理

①．Asp內(nèi)嵌的事務(wù)支持

例子：
use_transaction_1.asp
<%
'Asp中使用事務(wù)
Set conn=Server.CreateObject("ADODB.Connection")
conn.Open "course_dsn","course_user","course_password"
conn.begintrans '開始事務(wù)

sql="delete from user_info"
set rs=server.createobject("adodb.recordset")
rs.open sql,conn,3,3
if conn.errors.count>0 then '有錯誤發(fā)生
conn.rollbacktrans '回滾
set rs=nothing
conn.close
set conn=nothing
response.write "交易失敗，回滾至修改前的狀態(tài)！"
response.end
else
conn.committrans '提交事務(wù)
set rs=nothing
conn.close
set conn=nothing
response.write "交易成功！"
response.end
end if
%>

②．?dāng)?shù)據(jù)庫級的事務(wù)

i．創(chuàng)建存儲過程

ii．在Asp中調(diào)用

use_transaction_2.asp
<%
Set conn=Server.CreateObject("ADODB.Connection")
conn.Open "course_dsn","course_user","course_password"

sql="user_info_2 '"&request.querystring("user_name")&"','"&request.querystring("password")&"'"

set rs=server.createobject("adodb.recordset")
rs.open sql,conn,1,1
set rs=nothing
conn.close
set conn=nothing
%>

討論：兩種方式的優(yōu)劣？

⑶．使用視圖
在數(shù)據(jù)庫中定義好視圖之后，在Asp中如同使用一個表一樣來使用視圖

4．一個數(shù)據(jù)庫分頁的例子

db_page.asp
<%
on error resume next
Set conn=Server.CreateObject("ADODB.Connection") '創(chuàng)建連接數(shù)據(jù)庫的對象
conn.Open "course_dsn","course_user","course_password" '使用該對象連接數(shù)據(jù)庫
set rs=server.createObject("adodb.recordset")
sql="select * from user_info order by id desc"
rs.open sql,conn,1,1

if rs.recordcount>0 then '如果有記錄
rs.pagesize=2 '每頁最多顯示2條紀(jì)錄
'從URL獲取當(dāng)前要顯示的頁
page=cint(request("page"))
'頁面參數(shù)異常處理
if page="" then page=1
if page<1 then page=1
if page>= rs.pagecount then page=rs.pagecount
rs.absolutepage=page '當(dāng)前頁為page參數(shù)指定的頁
for i=1 to rs.pagesize '根據(jù)pagesize參數(shù)的大小循環(huán)顯示當(dāng)前頁中的紀(jì)錄
response.write "User_id："&rs("id")&"<br>"
response.write "User_name："&rs("user_name")&"<br><br>"
rs.movenext '紀(jì)錄指針下移
if rs.eof then exit for '如果到達(dá)紀(jì)錄集底部則退出循環(huán)
next
end if

'顯示翻頁按鈕
if page>1 then
response.write "<a href="&request.servervariables("document_name")&"?page=1>第一頁</a>　"
response.write "<a href="&request.servervariables("document_name")&"?page="&(page-1)&">上一頁</a>　"
end if
if page<>rs.pagecount then
response.write "<a href="&request.servervariables("document_name")&"?page="&(page+1)&">下一頁</a>　"
response.write "<a href="&request.servervariables("document_name")&"?page="&rs.pagecount&">最后一頁</a>　"
end if
response.write"頁碼："&page&"/"&rs.pagecount

'關(guān)閉對象，釋放內(nèi)存
rs.close
set rs=nothing
conn.close
set conn=nothing
%>

思考：分頁過程中使用了哪些額外的屬性？